Assigning Variable in a loop (batch file)

Question

I'll boil my overall problem down to a very simple question. How do I assign a variable within a for loop within a batch file?

If I use the following batch file in windows:

for %%f in (.\Update\!dos\*.zip) do (
    echo %%f
    set FileName3=%%f
    echo %FileName3%
    pause
)

It will echo the proper value for %%f but it echoes nothing for %FileName3%

I then tested it by directly assigning FileName3 a direct value like test, which failed.

In searching for solutions, a common pointer is to use is SETLOCAL enabledelayedexpansion

However, if I add that to the top of my batch file, it simply stops running. So while I think this is likely part of the solution, without the ability to run the batch file to test, I can't determine.

To be clear, with SETLOCAL enabledelayedexpansion at the top of my batch file, if I double click the file nothing happens. If I run it from a command line, it just goes back to the prompt as though nothing happened.

So my question is, how can I assign a variable within a loop in a batch file? If the answer is to use SETLOCAL enabledelayedexpansion, then why is adding that to my batch file causing it to do absolutely nothing.

Does this answer your question? [windows batch files: setting variable in for loop](https://stackoverflow.com/questions/5615206/windows-batch-files-setting-variable-in-for-loop) — Peter Duniho, Oct 20 '20 at 00:08
Does this answer your question? [Weird scope issue in .bat file](https://stackoverflow.com/questions/305605/weird-scope-issue-in-bat-file) — Peter Duniho, Oct 20 '20 at 00:21
Lacking an actual [mcve] it's impossible to say what's wrong with your batch file. There's no reason that the `setlocal` command would terminate your batch file. However, you _do_ need to make sure you use the variables correctly, i.e. use `!` instead of `%` to delimit variables that you want to participate in delayed expansion. See proposed duplicates, and many others, for all the information you should need. — Peter Duniho, Oct 20 '20 at 00:22

score 0 · Accepted Answer · answered Oct 20 '20 at 01:05

In your case, enabling delayed expansion at the top of your script will not work. The reason for that is that part of your source location includes the ! character, which due to delayed expansion will be omitted from the name, and your script will end because the path .\Update\dos\ does not exist.

The trick is to only enable delayed expansion, where you need it.

@Echo Off
SetLocal EnableExtensions DisableDelayedExpansion
If Not Exist "Update\!dos\*.zip" GoTo :EOF
For %%G In ("Update\!dos\*.zip") Do (
    Echo %%G
    Set "FileName3=%%G"
    SetLocal EnableDelayedExpansion
    Echo !FileName3!
    EndLocal
)
Pause

What you need to be aware of however, is that any of your variables which are defined during the loops SetLocal will become undefined at the next EndLocal. This means if you need those variables later in the code, you'll need to use a method of passing those over the EndLocal barrier. That however is out of the scope of your specific code example, so has not been included in this example.

thank you *very* much for your explanation. – eXo Oct 21 '20 at 01:26 — eXo, Oct 21 '20 at 01:26

Assigning Variable in a loop (batch file)

1 Answers1